CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6.4)
   2 include (CheckFunctionExists)
   3 include (CheckIncludeFile)
   4 include (CheckCXXSourceCompiles)
   5
   6
   7 project(SimGear)
   8
   9 # read 'version' file into a variable (stripping any newlines or spaces)
  10 file(READ version versionFile)
  11 string(STRIP ${versionFile} SIMGEAR_VERSION)
  12
  13 #packaging
  14 SET(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/COPYING")
  15 SET(CPACK_RESOURCE_FILE_README "${PROJECT_SOURCE_DIR}/README")
  16 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Simulation support libraries for FlightGear and related projects")
  17 SET(CPACK_PACKAGE_VENDOR "The FlightGear project")
  18 SET(CPACK_GENERATOR "TBZ2")
  19 SET(CPACK_INSTALL_CMAKE_PROJECTS  ${CMAKE_CURRENT_BINARY_DIR};SimGear;ALL;/)
  20
  21
  22 # split version string into components, note CMAKE_MATCH_0 is the entire regexp match
  23 string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" CPACK_PACKAGE_VERSION ${SIMGEAR_VERSION} )
  24 set(CPACK_PACKAGE_VERSION_MAJOR ${CMAKE_MATCH_1})
  25 set(CPACK_PACKAGE_VERSION_MINOR ${CMAKE_MATCH_2})
  26 set(CPACK_PACKAGE_VERSION_PATCH ${CMAKE_MATCH_3})
  27
  28 message(STATUS "version is ${CPACK_PACKAGE_VERSION_MAJOR} dot ${CPACK_PACKAGE_VERSION_MINOR} dot ${CPACK_PACKAGE_VERSION_PATCH}")
  29
  30 set(CPACK_SOURCE_GENERATOR TBZ2)
  31 set(CPACK_SOURCE_PACKAGE_FILE_NAME "simgear-${SIMGEAR_VERSION}" CACHE INTERNAL "tarball basename")
  32 set(CPACK_SOURCE_IGNORE_FILES
  33   "^${PROJECT_SOURCE_DIR}/.git;\\\\.gitignore;Makefile.am;~$;${CPACK_SOURCE_IGNORE_FILES}")
  34
  35 message(STATUS "ignoring: ${CPACK_SOURCE_IGNORE_FILES}")
  36
  37 include (CPack)
  38
  39 # We have some custom .cmake scripts not in the official distribution.
  40 set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/CMakeModules;${CMAKE_MODULE_PATH}")
  41
  42 # Change the default build type to something fast
  43 if(NOT CMAKE_BUILD_TYPE)
  44   set(CMAKE_BUILD_TYPE Release CACHE STRING
  45       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  46       FORCE)
  47 endif(NOT CMAKE_BUILD_TYPE)
  48
  49 option(SIMGEAR_SHARED "Set to ON to build SimGear as a shared library/framework" OFF)
  50 option(SIMGEAR_HEADLESS "Set to ON to build SimGear without GUI/graphics support" OFF)
  51 option(JPEG_FACTORY "Enable JPEG-factory support" OFF)
  52 option(ENABLE_LIBSVN "Set to ON to build SimGear with libsvnclient support" ON)
  53 option(ENABLE_RTI "Set to ON to build SimGear with RTI support" OFF)
  54
  55 if (MSVC)
  56   GET_FILENAME_COMPONENT(PARENT_DIR ${PROJECT_SOURCE_DIR} PATH)
  57   if (CMAKE_CL_64)
  58     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty.x64")
  59   else (CMAKE_CL_64)
  60     SET(TEST_3RDPARTY_DIR "${PARENT_DIR}/3rdparty")
  61   endif (CMAKE_CL_64)
  62   if (EXISTS ${TEST_3RDPARTY_DIR})
  63     set(MSVC_3RDPARTY_ROOT ${PARENT_DIR} CACHE PATH "Location where the third-party dependencies are extracted")
  64   else (EXISTS ${TEST_3RDPARTY_DIR})
  65     set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
  66   endif (EXISTS ${TEST_3RDPARTY_DIR})
  67 else (MSVC)
  68   set(MSVC_3RDPARTY_ROOT NOT_FOUND CACHE PATH "Location where the third-party dependencies are extracted")
  69 endif (MSVC)
  70
  71 if (MSVC AND MSVC_3RDPARTY_ROOT)
  72   message(STATUS "3rdparty files located in ${MSVC_3RDPARTY_ROOT}")
  73   set( OSG_MSVC "msvc" )
  74   if (${MSVC_VERSION} EQUAL 1600)
  75       set( OSG_MSVC ${OSG_MSVC}100 )
  76   else (${MSVC_VERSION} EQUAL 1600)
  77       set( OSG_MSVC ${OSG_MSVC}90 )
  78   endif (${MSVC_VERSION} EQUAL 1600)
  79   if (CMAKE_CL_64)
  80       set( OSG_MSVC ${OSG_MSVC}-64 )
  81       set( MSVC_3RDPARTY_DIR 3rdParty.x64 )
  82   else (CMAKE_CL_64)
  83       set( MSVC_3RDPARTY_DIR 3rdParty )
  84   endif (CMAKE_CL_64)
  85
  86   set (CMAKE_LIBRARY_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/lib )
  87   set (CMAKE_INCLUDE_PATH ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include ${MSVC_3RDPARTY_ROOT}/install/${OSG_MSVC}/OpenScenegraph/include)
  88   set (BOOST_ROOT ${MSVC_3RDPARTY_ROOT}/boost_1_44_0)
  89   message(STATUS "BOOST_ROOT is ${BOOST_ROOT}")
  90   set (OPENAL_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
  91   set (ALUT_INCLUDE_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/include)
  92   set (OPENAL_LIBRARY_DIR ${MSVC_3RDPARTY_ROOT}/${MSVC_3RDPARTY_DIR}/lib)
  93 endif (MSVC AND MSVC_3RDPARTY_ROOT)
  94
  95 find_package(Boost REQUIRED)
  96 set (BOOST_CXX_FLAGS "-DBOOST_MULTI_INDEX_DISABLE_SERIALIZATION -DBOOST_BIMAP_DISABLE_SERIALIZATION")
  97
  98 find_package(ZLIB REQUIRED)
  99 find_package(Threads REQUIRED)
 100
 101 if(SIMGEAR_HEADLESS)
 102     message(STATUS "headlesss mode")
 103     set(NO_OPENSCENEGRAPH_INTERFACE 1)
 104 else()
 105     find_package(OpenGL REQUIRED)
 106     find_package(OpenAL REQUIRED)
 107     find_package(ALUT REQUIRED)
 108     find_package(OpenSceneGraph 2.8.1 REQUIRED osgText osgSim osgDB osgParticle osgUtil)
 109 endif(SIMGEAR_HEADLESS)
 110
 111 if(JPEG_FACTORY)
 112     message(STATUS "JPEG-factory enabled")
 113     find_package(JPEG REQUIRED)
 114     include_directories(${JPEG_INCLUDE_DIR})
 115 endif(JPEG_FACTORY)
 116
 117 if(ENABLE_LIBSVN)
 118         find_package(SvnClient)
 119
 120         if(LIBSVN_FOUND)
 121                 message(STATUS "libsvn found, enabling in SimGear")
 122                 set(HAVE_SVN_CLIENT_H 1)
 123                 set(HAVE_LIBSVN_CLIENT_1 1)
 124         else()
 125                 message(STATUS "Missing libsvn, unable to enable SVN in SimGear")
 126         endif(LIBSVN_FOUND)
 127 endif(ENABLE_LIBSVN)
 128
 129 check_include_file(sys/time.h HAVE_SYS_TIME_H)
 130 check_include_file(sys/timeb.h HAVE_SYS_TIMEB_H)
 131 check_include_file(unistd.h HAVE_UNISTD_H)
 132 check_include_file(windows.h HAVE_WINDOWS_H)
 133
 134 if(ENABLE_RTI)
 135 # See if we have any rti library variant installed
 136     find_package(RTI)
 137 endif(ENABLE_RTI)
 138
 139 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 140 check_function_exists(ftime HAVE_FTIME)
 141 check_function_exists(timegm HAVE_TIMEGM)
 142 check_function_exists(rint HAVE_RINT)
 143 check_function_exists(mkdtemp HAVE_MKDTEMP)
 144
 145 if(HAVE_UNISTD_H)
 146     set(CMAKE_REQUIRED_INCLUDES ${CMAKE_INCLUDE_PATH})
 147     check_cxx_source_compiles(
 148        "#include <unistd.h>
 149         #if !defined(_POSIX_TIMERS) || (0 >= _POSIX_TIMERS)
 150             #error clock_gettime is not supported
 151         #endif
 152
 153         int main() { return 0; }
 154         "
 155         HAVE_CLOCK_GETTIME)
 156 endif(HAVE_UNISTD_H)
 157
 158 set(RT_LIBRARY "")
 159 if(HAVE_CLOCK_GETTIME)
 160     check_function_exists(clock_gettime CLOCK_GETTIME_IN_LIBC)
 161     if(NOT CLOCK_GETTIME_IN_LIBC)
 162         check_library_exists(rt clock_gettime "" HAVE_RT)
 163         if(HAVE_RT)
 164             set(RT_LIBRARY rt)
 165         endif(HAVE_RT)
 166         endif(NOT CLOCK_GETTIME_IN_LIBC)
 167 endif(HAVE_CLOCK_GETTIME)
 168
 169 SET(CMAKE_DEBUG_POSTFIX "d" CACHE STRING "add a postfix, usually d on windows")
 170 SET(CMAKE_RELEASE_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 171 SET(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 172 SET(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "add a postfix, usually empty on windows")
 173
 174 # isnan might not be real symbol, so can't check using function_exists
 175 check_cxx_source_compiles(
 176     "#include <cmath>
 177     void f() { isnan(0.0);} "
 178     HAVE_ISNAN)
 179
 180 if(CMAKE_COMPILER_IS_GNUCXX)
 181     set(WARNING_FLAGS -Wall)
 182 endif(CMAKE_COMPILER_IS_GNUCXX)
 183
 184 if(WIN32)
 185
 186     if(MSVC)
 187         # turn off various warnings
 188         # foreach(warning 4244 4251 4267 4275 4290 4786 4305 4996)
 189         #     SET(WARNING_FLAGS "${WARNING_FLAGS} /wd${warning}")
 190         # endforeach(warning)
 191
 192         set(MSVC_FLAGS "-DWIN32 -DNOMINMAX -D_USE_MATH_DEFINES -D_CRT_SECURE_NO_WARNINGS -D__CRT_NONSTDC_NO_WARNINGS /wd4996")
 193     endif(MSVC)
 194
 195     # assumed on Windows
 196     set(HAVE_GETLOCALTIME 1)
 197
 198     set( WINSOCK_LIBRARY "ws2_32.lib" )
 199     set( RT_LIBRARY "winmm" )
 200 endif(WIN32)
 201
 202 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS}")
 203 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} ${MSVC_FLAGS} ${BOOST_CXX_FLAGS}")
 204
 205 include_directories(${PROJECT_SOURCE_DIR})
 206 include_directories(${PROJECT_BINARY_DIR}/simgear)
 207
 208 include_directories(${OPENSCENEGRAPH_INCLUDE_DIRS}
 209     ${Boost_INCLUDE_DIRS} ${ZLIB_INCLUDE_DIR}
 210     ${ALUT_INCLUDE_DIR} ${OPENAL_INCLUDE_DIR} )
 211
 212
 213 add_definitions(-DHAVE_CONFIG_H)
 214
 215 # configure a header file to pass some of the CMake settings
 216 # to the source code
 217 configure_file (
 218   "${PROJECT_SOURCE_DIR}/simgear/simgear_config_cmake.h.in"
 219   "${PROJECT_BINARY_DIR}/simgear/simgear_config.h"
 220   )
 221
 222 # enable CTest / make test target
 223
 224 include (Dart)
 225 enable_testing()
 226
 227 install (FILES ${PROJECT_BINARY_DIR}/simgear/simgear_config.h  DESTINATION include/simgear/)
 228 add_subdirectory(simgear)
 229
 230 #-----------------------------------------------------------------------------
 231 ### uninstall target
 232 #-----------------------------------------------------------------------------
 233 CONFIGURE_FILE(
 234   "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules/cmake_uninstall.cmake.in"
 235   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 236   IMMEDIATE @ONLY)
 237 ADD_CUSTOM_TARGET(uninstall
 238   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 239
 240
 241