package/Win32-Inno/FlightGear-1.9.iss

   1 ; Script generated by the Inno Setup Script Wizard.
   2 ; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!
   3 ;
   4 ; This script creates an installable FlightGear package for Win32 using the
   5 ; "Inno Setup" package builder.  Inno Setup is free (but probably not open
   6 ; source?.)  The official web site for this package building software is:
   7 ;
   8 ;     http://www.jrsoftware.org/isinfo.php
   9 ;
  10 ; Note: the files must appear in the X: drive.
  11 ; You can do this with the command below:
  12 ;
  13 ;     subst X: path_to_files
  14 ;
  15 ; For example:
  16 ;
  17 ;     C:\> subst X: F:\Path\to\FlightGear\root
  18 ;     C:\> subst X: F:\
  19 ;
  20
  21 [Setup]
  22 AppName=FlightGear
  23 OutputBaseFilename=fgsetup-1.9.1
  24 AppVerName=FlightGear v1.9.1
  25 AppPublisher=The FlightGear Organization
  26 AppPublisherURL=http://www.flightgear.org
  27 AppSupportURL=http://www.flightgear.org
  28 AppUpdatesURL=http://www.flightgear.org
  29 DefaultDirName={pf}\FlightGear
  30 DefaultGroupName=FlightGear v1.9.1
  31 LicenseFile=X:\data\COPYING
  32 Uninstallable=yes
  33 SetupIconFile=x:\flightgear.ico
  34 VersionInfoVersion=1.9.1.0
  35 WizardImageFile=X:\setupimg.bmp
  36 WizardSmallImageFile=X:\setupsmall.bmp
  37
  38 [Tasks]
  39 ; NOTE: The following entry contains English phrases ("Create a desktop icon" and "Additional icons"). You are free to translate them into another language if required.
  40 Name: "desktopicon"; Description: "Create a &desktop icon"; GroupDescription: "Additional icons:"
  41 Name: "insoal"; Description: "Install OpenAL (the sound engine)"
  42
  43 [Files]
  44 ; NOTE: run subst X: F:\ (or whatever path the expanded tree resides at)
  45 Source: "X:\*.txt"; DestDir: "{app}"; Flags: ignoreversion
  46 Source: "X:\bin\*.*"; DestDir: "{app}\bin"; Flags: ignoreversion recursesubdirs
  47 Source: "X:\data\*.*"; DestDir: "{app}\data"; Flags: ignoreversion recursesubdirs
  48 ; NOTE: Don't use "Flags: ignoreversion" on any shared system files
  49
  50 [Icons]
  51 Name: "{group}\FlightGear Launcher"; Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}";
  52 ; Name: "{group}\FlightGear"; Filename: "{app}\bin\Win32\fgfs.exe"; Parameters: "--fg-root=."; WorkingDir: "{app}";
  53 Name: "{group}\FlightGear Manual"; Filename: "{app}\data\Docs\getstart.pdf"
  54 Name: "{group}\FlightGear Documentation"; Filename: "{app}\data\Docs\index.html"
  55 Name: "{group}\Flightgear Wiki"; Filename: "http://wiki.flightgear.org"
  56 Name: "{userdesktop}\FlightGear v1.9.1"; Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}"; Tasks: desktopicon
  57
  58 Name: "{group}\Tools\Install & Uninstall Scenery"; Filename: "{app}\bin\Win32\fgadmin.exe"; WorkingDir: "{app}";
  59 Name: "{group}\Tools\TerraSync"; Filename: "{app}\bin\Win32\terrasync.exe"; Parameters: "-S -p 5505 -d ""{app}\terrasync"""; WorkingDir: "{app}";
  60 Name: "{group}\Tools\Uninstall FlightGear"; Filename: "{uninstallexe}"
  61
  62 Name: "{group}\Tools\fgjs"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\fgjs.exe"" ""--fg-root={app}\data"""; WorkingDir: "{app}\bin\Win32";
  63 Name: "{group}\Tools\GPSsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\GPSsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  64 Name: "{group}\Tools\UGsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\UGsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  65 Name: "{group}\Tools\MIDSsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\MIDSsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  66 Name: "{group}\Tools\metar"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\metar.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  67 Name: "{group}\Tools\yasim"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\yasim.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  68
  69 Name: "{group}\Tools\Explore Documentation Folder"; Filename: "{app}\data\Docs"
  70
  71 ; For running flightgear directly
  72 ; Name: "{userdesktop}\FlightGear v1.9.1"; Filename: "{app}\bin\Win32\fgfs.exe"; Parameters: "--fg-root=."; WorkingDir: "{app}"; Tasks: desktopicon
  73
  74 [Run]
  75 ; Put installation directory into the fgrun.prefs
  76 filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}\bin\Win32"; Parameters: "--silent ""--fg-exe={app}\bin\Win32\fgfs.exe"" ""--fg-root={app}\data"" ""--fg-scenery={app}\data\Scenery;{app}\scenery;{app}\terrasync"""
  77
  78 ; Put installation and source directories into the fgadmin.prefs
  79 filename: "{app}\bin\Win32\fgadmin.exe"; WorkingDir: "{app}\bin\Win32"; Parameters: "--silent ""--install-source={src}\..\Scenery"" ""--scenery-dest={app}\scenery"""
  80
  81 ; Make the user installable scenery directory
  82 filename: "{app}\bin\Win32\mkscenerydir.bat"; WorkingDir: "{app}"
  83
  84 Filename: "{app}\bin\OpenAL\oalinst.exe"; WorkingDir: "{app}"; Description: "Installing OpenAL"; Tasks: insoal
  85
  86 Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}"; Description: "Launch FlightGear"; Flags: postinstall skipifsilent
  87