package/Win32-Inno/FlightGear-devel.iss

   1 ; Script generated by the Inno Setup Script Wizard.
   2 ; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!
   3 ;
   4 ; This script creates an installable FlightGear package for Win32 using the
   5 ; "Inno Setup" package builder.  Inno Setup is free (but probably not open
   6 ; source?.)  The official web site for this package building software is:
   7 ;
   8 ;     http://www.jrsoftware.org/isinfo.php
   9 ;
  10 ; Note: the files must appear in the X: drive.
  11 ; You can do this with the command below:
  12 ;
  13 ;     subst X: path_to_files
  14 ;
  15 ; For example:
  16 ;
  17 ;     C:\> subst X: F:\Path\to\FlightGear\root
  18 ;     C:\> subst X: F:\
  19 ;     C:\> subst X: E:\Package\FlightGear-YYYYMMDD
  20 ;     C:\> subst X: /d
  21 ;
  22
  23 #define FGVER "v20111024"\r
  24 ;#define FGVER "2.4.0"\r
  25
  26 [Setup]
  27 AppId=FlightGear {#FGVER}
  28 AppName=FlightGear {#FGVER}
  29 AppPublisher=The FlightGear Team
  30 OutputBaseFilename=Setup FlightGear {#FGVER}
  31 AppVerName=FlightGear {#FGVER}
  32 AppPublisherURL=http://www.flightgear.org
  33 AppSupportURL=http://www.flightgear.org
  34 AppUpdatesURL=http://www.flightgear.org
  35 DefaultDirName={pf}\FlightGear {#FGVER}
  36 DefaultGroupName=FlightGear {#FGVER}
  37 LicenseFile=X:\data\COPYING
  38 Uninstallable=yes
  39 SetupIconFile=x:\flightgear.ico
  40 VersionInfoVersion=2.5.0.0
  41 WizardImageFile=X:\setupimg.bmp
  42 WizardImageStretch=No
  43 WizardSmallImageFile=X:\setupsmall.bmp
  44 VersionInfoCompany=The FlightGear Team
  45 UninstallDisplayIcon={app}\bin\Win32\fgrun.exe
  46
  47 [Tasks]
  48 ; NOTE: The following entry contains English phrases ("Create a desktop icon" and "Additional icons"). You are free to translate them into another language if required.
  49 Name: "desktopicon"; Description: "Create a &desktop icon"; GroupDescription: "Additional icons:"
  50 Name: "insoal"; Description: "Install OpenAL (the sound engine)"
  51
  52 [Files]
  53 ; NOTE: run subst X: F:\ (or whatever path the expanded tree resides at)
  54 Source: "X:\*.txt"; DestDir: "{app}"; Flags: ignoreversion
  55 Source: "X:\bin\Win32\*.*"; DestDir: "{app}\bin\Win32"; Flags: ignoreversion recursesubdirs
  56 ;;; Source: "X:\bin\vcredist_x86.exe"; DestDir: "{app}\bin"; Flags: ignoreversion
  57 Source: "X:\bin\oalinst.exe"; DestDir: "{app}\bin"; Flags: ignoreversion
  58 Source: "X:\data\*.*"; DestDir: "{app}\data"; Flags: ignoreversion recursesubdirs
  59 ; NOTE: Don't use "Flags: ignoreversion" on any shared system files
  60
  61 [Dirs]
  62 ; Make the user installable scenery directory
  63 Name: "{app}\scenery"; Permissions: everyone-modify
  64 Name: "{code:TerrasyncDir}"; Permissions: everyone-modify
  65
  66 [Icons]
  67 Name: "{group}\FlightGear {#FGVER}"; Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}";
  68 ; Name: "{group}\FlightGear"; Filename: "{app}\bin\Win32\fgfs.exe"; Parameters: "--fg-root=."; WorkingDir: "{app}";
  69 Name: "{group}\FlightGear Manual"; Filename: "{app}\data\Docs\getstart.pdf"
  70 Name: "{group}\FlightGear Documentation"; Filename: "{app}\data\Docs\index.html"
  71 Name: "{group}\Flightgear Wiki"; Filename: "http://wiki.flightgear.org"
  72 Name: "{userdesktop}\FlightGear {#FGVER}"; Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}"; Tasks: desktopicon
  73
  74 Name: "{group}\Tools\Install & Uninstall Scenery"; Filename: "{app}\bin\Win32\fgadmin.exe"; WorkingDir: "{app}";
  75 Name: "{group}\Tools\TerraSync"; Filename: "{app}\bin\Win32\terrasync.exe"; Parameters: "-S -p 5505 -d ""{app}\terrasync"""; WorkingDir: "{app}";
  76 Name: "{group}\Tools\Uninstall FlightGear {#FGVER}"; Filename: "{uninstallexe}"
  77
  78 Name: "{group}\Tools\js_demo"; Filename: "{app}\bin\Win32\js_demo.exe"
  79 Name: "{group}\Tools\fgjs"; Filename: "cmd"; Parameters: "/k fgjs.exe ""--fg-root={app}\data"""; WorkingDir: "{app}\bin\Win32";
  80 Name: "{group}\Tools\GPSsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\GPSsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  81 Name: "{group}\Tools\UGsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\UGsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  82 Name: "{group}\Tools\MIDSsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\MIDSsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  83 Name: "{group}\Tools\metar"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\metar.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  84 Name: "{group}\Tools\yasim"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\yasim.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  85
  86 Name: "{group}\Tools\Explore Documentation Folder"; Filename: "{app}\data\Docs"
  87
  88 ; For running flightgear directly
  89 ; Name: "{userdesktop}\FlightGear {#FGVER}"; Filename: "{app}\bin\Win32\fgfs.exe"; Parameters: "--fg-root=."; WorkingDir: "{app}"; Tasks: desktopicon
  90
  91 [Run]
  92 ;;; Filename: "{app}\bin\vcredist_x86.exe"; WorkingDir: "{app}"; Parameters: "/qb!"; Description: "Installing Flightgear prerequisites"
  93
  94 ; Put installation directory into the fgrun.prefs
  95 filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}\bin\Win32"; Parameters: "--silent ""--fg-exe={app}\bin\Win32\fgfs.exe"" ""--ts-exe={app}\bin\Win32\terrasync.exe"" ""--fg-root={app}\data"" ""--fg-scenery={app}\data\Scenery;{app}\scenery;{code:TerrasyncDir}"" --ts-dir=3"
  96
  97 ; Put installation and source directories into the fgadmin.prefs
  98 filename: "{app}\bin\Win32\fgadmin.exe"; WorkingDir: "{app}\bin\Win32"; Parameters: "--silent ""--install-source={src}\..\Scenery"" ""--scenery-dest={app}\scenery"""
  99 Filename: "{app}\bin\oalinst.exe"; WorkingDir: "{app}"; Description: "Installing OpenAL"; Tasks: insoal
 100 ;Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}"; Description: "Launch FlightGear"; Flags: postinstall skipifsilent
 101
 102 [Registry]
 103 Root: HKLM; Subkey: "Software\flightgear.org"; ValueType: string; ValueName: "TerrasyncDir"; ValueData: "{code:TerrasyncDir}"
 104
 105 [Code]
 106 var
 107   TerrasyncDirPage: TInputDirWizardPage;
 108
 109 procedure URLLabelOnClick(Sender: TObject);
 110 var
 111   ErrorCode: Integer;
 112 begin
 113   ShellExec('open', 'http://www.flightgear.org', '', '', SW_SHOWNORMAL, ewNoWait, ErrorCode);
 114 end;
 115
 116 procedure CreateURLLabel(ParentForm: TSetupForm; CancelButton: TNewButton);
 117 var
 118   URLLabel: TNewStaticText;
 119 begin
 120   URLLabel := TNewStaticText.Create(ParentForm);
 121   URLLabel.Caption := 'www.flightgear.org';
 122   URLLabel.Cursor := crHand;
 123   URLLabel.OnClick := @URLLabelOnClick;
 124   URLLabel.Parent := ParentForm;
 125   { Alter Font *after* setting Parent so the correct defaults are inherited first }
 126   URLLabel.Font.Style := URLLabel.Font.Style + [fsUnderline];
 127   URLLabel.Font.Color := clBlue;
 128   URLLabel.Top := CancelButton.Top + CancelButton.Height - URLLabel.Height - 2;
 129   URLLabel.Left := ScaleX(20);
 130 end;
 131
 132 procedure InitializeWizard();
 133 begin
 134   TerrasyncDirPage := CreateInputDirPage(wpSelectDir,
 135     'Select Terrasync Directory', 'Where should scenery downloaded by Terrasync be put?',
 136     'Select the folder in which Terrasync would download additional scenery, then click Next.',
 137     False, 'Terrasync Folder');
 138   TerrasyncDirPage.Add('');
 139
 140   CreateURLLabel(WizardForm, WizardForm.CancelButton);
 141 end;
 142
 143 function NextButtonClick(CurPageID: Integer): Boolean;
 144 begin
 145   if CurPageID = wpSelectDir then begin
 146     TerrasyncDirPage.Values[0] := GetPreviousData( 'TerrasyncDir', ExpandConstant('{reg:HKLM\Software\flightgear.org,TerrasyncDir|{app}\terrasync}') );
 147   end;
 148   Result := True;
 149 end;
 150
 151 function TerrasyncDir(Param: String): String;
 152 begin
 153   Result := TerrasyncDirPage.Values[0];
 154 end;
 155
 156 procedure RegisterPreviousData(PreviousDataKey: Integer);
 157 begin
 158   { Store the settings so we can restore them next time }
 159   SetPreviousData(PreviousDataKey, 'TerrasyncDir', TerrasyncDirPage.Values[0]);
 160 end;
 161
 162 function UpdateReadyMemo(Space, NewLine, MemoUserInfoInfo, MemoDirInfo, MemoTypeInfo, MemoComponentsInfo, MemoGroupInfo, MemoTasksInfo: String): String;
 163 var
 164   S: String;
 165 begin
 166   S := '';
 167   S := S + MemoDirInfo + NewLine + NewLine;
 168   S := S + 'Terrasync folder:' + NewLine;
 169   S := S + Space + TerrasyncDirPage.Values[0] + NewLine + NewLine;
 170   S := S + MemoGroupInfo + NewLine + NewLine;
 171   S := S + MemoTasksInfo + NewLine + NewLine;
 172
 173   Result := S;
 174 end;