package/Win32-Inno/FlightGear-devel.iss

   1 ; Script generated by the Inno Setup Script Wizard.
   2 ; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!
   3 ;
   4 ; This script creates an installable FlightGear package for Win32 using the
   5 ; "Inno Setup" package builder.  Inno Setup is free (but probably not open
   6 ; source?.)  The official web site for this package building software is:
   7 ;
   8 ;     http://www.jrsoftware.org/isinfo.php
   9 ;
  10 ; Note: the files must appear in the X: drive.
  11 ; You can do this with the command below:
  12 ;
  13 ;     subst X: path_to_files
  14 ;
  15 ; For example:
  16 ;
  17 ;     C:\> subst X: F:\Path\to\FlightGear\root
  18 ;     C:\> subst X: F:\
  19 ;     C:\> subst X: E:\Package\FlightGear-YYYYMMDD
  20 ;     C:\> subst X: /d
  21 ;
  22
  23 #define FGVER "v20110228"
  24
  25 [Setup]
  26 AppId=FlightGear {#FGVER}
  27 AppName=FlightGear {#FGVER}
  28 AppPublisher=The FlightGear Team
  29 OutputBaseFilename=Setup FlightGear {#FGVER}
  30 AppVerName=FlightGear {#FGVER}
  31 AppPublisherURL=http://www.flightgear.org
  32 AppSupportURL=http://www.flightgear.org
  33 AppUpdatesURL=http://www.flightgear.org
  34 DefaultDirName={pf}\FlightGear {#FGVER}
  35 DefaultGroupName=FlightGear {#FGVER}
  36 LicenseFile=X:\data\COPYING
  37 Uninstallable=yes
  38 SetupIconFile=x:\flightgear.ico
  39 VersionInfoVersion=2.0.0.0
  40 WizardImageFile=X:\setupimg.bmp
  41 WizardImageStretch=No
  42 WizardSmallImageFile=X:\setupsmall.bmp
  43 VersionInfoCompany=The FlightGear Team
  44 UninstallDisplayIcon={app}\bin\Win32\fgrun.exe
  45
  46 [Tasks]
  47 ; NOTE: The following entry contains English phrases ("Create a desktop icon" and "Additional icons"). You are free to translate them into another language if required.
  48 Name: "desktopicon"; Description: "Create a &desktop icon"; GroupDescription: "Additional icons:"
  49 Name: "insoal"; Description: "Install OpenAL (the sound engine)"
  50
  51 [Files]
  52 ; NOTE: run subst X: F:\ (or whatever path the expanded tree resides at)
  53 Source: "X:\*.txt"; DestDir: "{app}"; Flags: ignoreversion
  54 Source: "X:\bin\Win32\*.*"; DestDir: "{app}\bin\Win32"; Flags: ignoreversion recursesubdirs
  55 Source: "X:\bin\vcredist_x86.exe"; DestDir: "{app}\bin"; Flags: ignoreversion
  56 Source: "X:\bin\oalinst.exe"; DestDir: "{app}\bin"; Flags: ignoreversion
  57 Source: "X:\data\*.*"; DestDir: "{app}\data"; Flags: ignoreversion recursesubdirs
  58 ; NOTE: Don't use "Flags: ignoreversion" on any shared system files
  59
  60 [Dirs]
  61 ; Make the user installable scenery directory
  62 Name: "{app}\scenery"; Permissions: everyone-modify
  63 Name: "{code:TerrasyncDir}"; Permissions: everyone-modify
  64
  65 [Icons]
  66 Name: "{group}\FlightGear {#FGVER}"; Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}";
  67 ; Name: "{group}\FlightGear"; Filename: "{app}\bin\Win32\fgfs.exe"; Parameters: "--fg-root=."; WorkingDir: "{app}";
  68 Name: "{group}\FlightGear Manual"; Filename: "{app}\data\Docs\getstart.pdf"
  69 Name: "{group}\FlightGear Documentation"; Filename: "{app}\data\Docs\index.html"
  70 Name: "{group}\Flightgear Wiki"; Filename: "http://wiki.flightgear.org"
  71 Name: "{userdesktop}\FlightGear {#FGVER}"; Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}"; Tasks: desktopicon
  72
  73 Name: "{group}\Tools\Install & Uninstall Scenery"; Filename: "{app}\bin\Win32\fgadmin.exe"; WorkingDir: "{app}";
  74 Name: "{group}\Tools\TerraSync"; Filename: "{app}\bin\Win32\terrasync.exe"; Parameters: "-S -p 5505 -d ""{app}\terrasync"""; WorkingDir: "{app}";
  75 Name: "{group}\Tools\Uninstall FlightGear {#FGVER}"; Filename: "{uninstallexe}"
  76
  77 Name: "{group}\Tools\js_demo"; Filename: "{app}\bin\Win32\js_demo.exe"
  78 Name: "{group}\Tools\fgjs"; Filename: "cmd"; Parameters: "/k fgjs.exe ""--fg-root={app}\data"""; WorkingDir: "{app}\bin\Win32";
  79 Name: "{group}\Tools\GPSsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\GPSsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  80 Name: "{group}\Tools\UGsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\UGsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  81 Name: "{group}\Tools\MIDSsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\MIDSsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  82 Name: "{group}\Tools\metar"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\metar.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  83 Name: "{group}\Tools\yasim"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\yasim.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  84
  85 Name: "{group}\Tools\Explore Documentation Folder"; Filename: "{app}\data\Docs"
  86
  87 ; For running flightgear directly
  88 ; Name: "{userdesktop}\FlightGear {#FGVER}"; Filename: "{app}\bin\Win32\fgfs.exe"; Parameters: "--fg-root=."; WorkingDir: "{app}"; Tasks: desktopicon
  89
  90 [Run]
  91 Filename: "{app}\bin\vcredist_x86.exe"; WorkingDir: "{app}"; Parameters: "/qb!"; Description: "Installing Flightgear prerequisites"
  92
  93 ; Put installation directory into the fgrun.prefs
  94 filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}\bin\Win32"; Parameters: "--silent ""--fg-exe={app}\bin\Win32\fgfs.exe"" ""--ts-exe={app}\bin\Win32\terrasync.exe"" ""--fg-root={app}\data"" ""--fg-scenery={app}\data\Scenery;{app}\scenery;{code:TerrasyncDir}"" --ts-dir=3"
  95
  96 ; Put installation and source directories into the fgadmin.prefs
  97 filename: "{app}\bin\Win32\fgadmin.exe"; WorkingDir: "{app}\bin\Win32"; Parameters: "--silent ""--install-source={src}\..\Scenery"" ""--scenery-dest={app}\scenery"""
  98 Filename: "{app}\bin\oalinst.exe"; WorkingDir: "{app}"; Description: "Installing OpenAL"; Tasks: insoal
  99 ;Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}"; Description: "Launch FlightGear"; Flags: postinstall skipifsilent
 100
 101 [Registry]
 102 Root: HKLM; Subkey: "Software\flightgear.org {#FGVER}"; ValueType: string; ValueName: "TerrasyncDir"; ValueData: "{code:TerrasyncDir}"
 103
 104 [Code]
 105 var
 106   TerrasyncDirPage: TInputDirWizardPage;
 107
 108 procedure URLLabelOnClick(Sender: TObject);
 109 var
 110   ErrorCode: Integer;
 111 begin
 112   ShellExec('open', 'http://www.flightgear.org', '', '', SW_SHOWNORMAL, ewNoWait, ErrorCode);
 113 end;
 114
 115 procedure CreateURLLabel(ParentForm: TSetupForm; CancelButton: TNewButton);
 116 var
 117   URLLabel: TNewStaticText;
 118 begin
 119   URLLabel := TNewStaticText.Create(ParentForm);
 120   URLLabel.Caption := 'www.flightgear.org';
 121   URLLabel.Cursor := crHand;
 122   URLLabel.OnClick := @URLLabelOnClick;
 123   URLLabel.Parent := ParentForm;
 124   { Alter Font *after* setting Parent so the correct defaults are inherited first }
 125   URLLabel.Font.Style := URLLabel.Font.Style + [fsUnderline];
 126   URLLabel.Font.Color := clBlue;
 127   URLLabel.Top := CancelButton.Top + CancelButton.Height - URLLabel.Height - 2;
 128   URLLabel.Left := ScaleX(20);
 129 end;
 130
 131 procedure InitializeWizard();
 132 begin
 133   TerrasyncDirPage := CreateInputDirPage(wpSelectDir,
 134     'Select Terrasync Directory', 'Where should scenery downloaded by Terrasync be put?',
 135     'Select the folder in which Terrasync would download additional scenery, then click Next.',
 136     False, 'Terrasync Folder');
 137   TerrasyncDirPage.Add('');
 138
 139   CreateURLLabel(WizardForm, WizardForm.CancelButton);
 140 end;
 141
 142 function NextButtonClick(CurPageID: Integer): Boolean;
 143 begin
 144   if CurPageID = wpSelectDir then begin
 145     TerrasyncDirPage.Values[0] := GetPreviousData( 'TerrasyncDir', ExpandConstant('{reg:HKLM\Software\flightgear.org,TerrasyncDir|{app}\terrasync}') );
 146   end;
 147   Result := True;
 148 end;
 149
 150 function TerrasyncDir(Param: String): String;
 151 begin
 152   Result := TerrasyncDirPage.Values[0];
 153 end;
 154
 155 procedure RegisterPreviousData(PreviousDataKey: Integer);
 156 begin
 157   { Store the settings so we can restore them next time }
 158   SetPreviousData(PreviousDataKey, 'TerrasyncDir', TerrasyncDirPage.Values[0]);
 159 end;
 160
 161 function UpdateReadyMemo(Space, NewLine, MemoUserInfoInfo, MemoDirInfo, MemoTypeInfo, MemoComponentsInfo, MemoGroupInfo, MemoTasksInfo: String): String;
 162 var
 163   S: String;
 164 begin
 165   S := '';
 166   S := S + MemoDirInfo + NewLine + NewLine;
 167   S := S + 'Terrasync folder:' + NewLine;
 168   S := S + Space + TerrasyncDirPage.Values[0] + NewLine + NewLine;
 169   S := S + MemoGroupInfo + NewLine + NewLine;
 170   S := S + MemoTasksInfo + NewLine + NewLine;
 171
 172   Result := S;
 173 end;