package/Win32-Inno/FlightGear.iss

   1 ; Script generated by the Inno Setup Script Wizard.
   2 ; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!
   3 ;
   4 ; This script creates an installable FlightGear package for Win32 using the
   5 ; "Inno Setup" package builder.  Inno Setup is free (but probably not open
   6 ; source?.)  The official web site for this package building software is:
   7 ;
   8 ;     http://www.jrsoftware.org/isinfo.php
   9 ;
  10 ; Note: the files must appear in the X: drive.
  11 ; You can do this with the command below:
  12 ;
  13 ;     subst X: path_to_files
  14 ;
  15 ; For example:
  16 ;
  17 ;     C:\> subst X: F:\Path\to\FlightGear\root
  18 ;     C:\> subst X: F:\
  19 ;
  20
  21 [Setup]
  22 AppId=FlightGear
  23 AppName=FlightGear
  24 AppPublisher=The FlightGear Team
  25 OutputBaseFilename=fgsetup-2.0.0
  26 AppVerName=FlightGear v2.0.0
  27 AppPublisherURL=http://www.flightgear.org
  28 AppSupportURL=http://www.flightgear.org
  29 AppUpdatesURL=http://www.flightgear.org
  30 DefaultDirName={pf}\FlightGear
  31 DefaultGroupName=FlightGear v2.0.0
  32 LicenseFile=X:\data\COPYING
  33 Uninstallable=yes
  34 SetupIconFile=x:\flightgear.ico
  35 VersionInfoVersion=2.0.0.0
  36 WizardImageFile=X:\setupimg.bmp
  37 WizardImageStretch=No
  38 WizardSmallImageFile=X:\setupsmall.bmp
  39 VersionInfoCompany=The FlightGear Team
  40 UninstallDisplayIcon={app}\bin\Win32\fgrun.exe
  41
  42 [Tasks]
  43 ; NOTE: The following entry contains English phrases ("Create a desktop icon" and "Additional icons"). You are free to translate them into another language if required.
  44 Name: "desktopicon"; Description: "Create a &desktop icon"; GroupDescription: "Additional icons:"
  45 Name: "insoal"; Description: "Install OpenAL (the sound engine)"
  46
  47 [Files]
  48 ; NOTE: run subst X: F:\ (or whatever path the expanded tree resides at)
  49 Source: "X:\*.txt"; DestDir: "{app}"; Flags: ignoreversion
  50 Source: "X:\bin\Win32\*.*"; DestDir: "{app}\bin\Win32"; Flags: ignoreversion recursesubdirs
  51 Source: "X:\bin\vcredist_x86.exe"; DestDir: "{app}\bin"; Flags: ignoreversion
  52 Source: "X:\bin\OpenAL\oalinst.exe"; DestDir: "{app}\bin\OpenAL"; Flags: ignoreversion
  53 Source: "X:\data\*.*"; DestDir: "{app}\data"; Flags: ignoreversion recursesubdirs
  54 ; NOTE: Don't use "Flags: ignoreversion" on any shared system files
  55
  56 [Dirs]
  57 ; Make the user installable scenery directory
  58 Name: "{app}\scenery"; Permissions: everyone-modify
  59 Name: "{code:TerrasyncDir}"; Permissions: everyone-modify
  60
  61 [Icons]
  62 Name: "{group}\FlightGear Launcher"; Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}";
  63 ; Name: "{group}\FlightGear"; Filename: "{app}\bin\Win32\fgfs.exe"; Parameters: "--fg-root=."; WorkingDir: "{app}";
  64 Name: "{group}\FlightGear Manual"; Filename: "{app}\data\Docs\getstart.pdf"
  65 Name: "{group}\FlightGear Documentation"; Filename: "{app}\data\Docs\index.html"
  66 Name: "{group}\Flightgear Wiki"; Filename: "http://wiki.flightgear.org"
  67 Name: "{userdesktop}\FlightGear v2.0.0"; Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}"; Tasks: desktopicon
  68
  69 Name: "{group}\Tools\Install & Uninstall Scenery"; Filename: "{app}\bin\Win32\fgadmin.exe"; WorkingDir: "{app}";
  70 Name: "{group}\Tools\TerraSync"; Filename: "{app}\bin\Win32\terrasync.exe"; Parameters: "-S -p 5505 -d ""{app}\terrasync"""; WorkingDir: "{app}";
  71 Name: "{group}\Tools\Uninstall FlightGear"; Filename: "{uninstallexe}"
  72
  73 Name: "{group}\Tools\js_demo"; Filename: "{app}\bin\Win32\js_demo.exe"
  74 Name: "{group}\Tools\fgjs"; Filename: "cmd"; Parameters: "/k fgjs.exe ""--fg-root={app}\data"""; WorkingDir: "{app}\bin\Win32";
  75 Name: "{group}\Tools\GPSsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\GPSsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  76 Name: "{group}\Tools\UGsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\UGsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  77 Name: "{group}\Tools\MIDSsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\MIDSsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  78 Name: "{group}\Tools\metar"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\metar.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  79 Name: "{group}\Tools\yasim"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\yasim.exe"" -h"; WorkingDir: "{app}\bin\Win32";
  80
  81 Name: "{group}\Tools\Explore Documentation Folder"; Filename: "{app}\data\Docs"
  82
  83 ; For running flightgear directly
  84 ; Name: "{userdesktop}\FlightGear v2.0.0"; Filename: "{app}\bin\Win32\fgfs.exe"; Parameters: "--fg-root=."; WorkingDir: "{app}"; Tasks: desktopicon
  85
  86 [Run]
  87 Filename: "{app}\bin\vcredist_x86.exe"; WorkingDir: "{app}"; Parameters: "/qb!"; Description: "Installing Flightgear prerequisites"
  88
  89 ; Put installation directory into the fgrun.prefs
  90 filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}\bin\Win32"; Parameters: "--silent ""--fg-exe={app}\bin\Win32\fgfs.exe"" ""--ts-exe={app}\bin\Win32\terrasync.exe"" ""--fg-root={app}\data"" ""--fg-scenery={app}\data\Scenery;{app}\scenery;{code:TerrasyncDir}"" --ts-dir=3"
  91
  92 ; Put installation and source directories into the fgadmin.prefs
  93 filename: "{app}\bin\Win32\fgadmin.exe"; WorkingDir: "{app}\bin\Win32"; Parameters: "--silent ""--install-source={src}\..\Scenery"" ""--scenery-dest={app}\scenery"""
  94 Filename: "{app}\bin\OpenAL\oalinst.exe"; WorkingDir: "{app}"; Description: "Installing OpenAL"; Tasks: insoal
  95 ;Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}"; Description: "Launch FlightGear"; Flags: postinstall skipifsilent
  96
  97 [Registry]
  98 Root: HKLM; Subkey: "Software\flightgear.org"; ValueType: string; ValueName: "TerrasyncDir"; ValueData: "{code:TerrasyncDir}"
  99
 100 [Code]
 101 var
 102   TerrasyncDirPage: TInputDirWizardPage;
 103
 104 procedure URLLabelOnClick(Sender: TObject);
 105 var
 106   ErrorCode: Integer;
 107 begin
 108   ShellExec('open', 'http://www.flightgear.org', '', '', SW_SHOWNORMAL, ewNoWait, ErrorCode);
 109 end;
 110
 111 procedure CreateURLLabel(ParentForm: TSetupForm; CancelButton: TNewButton);
 112 var
 113   URLLabel: TNewStaticText;
 114 begin
 115   URLLabel := TNewStaticText.Create(ParentForm);
 116   URLLabel.Caption := 'www.flightgear.org';
 117   URLLabel.Cursor := crHand;
 118   URLLabel.OnClick := @URLLabelOnClick;
 119   URLLabel.Parent := ParentForm;
 120   { Alter Font *after* setting Parent so the correct defaults are inherited first }
 121   URLLabel.Font.Style := URLLabel.Font.Style + [fsUnderline];
 122   URLLabel.Font.Color := clBlue;
 123   URLLabel.Top := CancelButton.Top + CancelButton.Height - URLLabel.Height - 2;
 124   URLLabel.Left := ScaleX(20);
 125 end;
 126
 127 procedure InitializeWizard();
 128 begin
 129   TerrasyncDirPage := CreateInputDirPage(wpSelectDir,
 130     'Select Terrasync Directory', 'Where should scenery downloaded by Terrasync be put?',
 131     'Select the folder in which Terrasync would download additional scenery, then click Next.',
 132     False, 'Terrasync Folder');
 133   TerrasyncDirPage.Add('');
 134
 135   CreateURLLabel(WizardForm, WizardForm.CancelButton);
 136 end;
 137
 138 function NextButtonClick(CurPageID: Integer): Boolean;
 139 begin
 140   if CurPageID = wpSelectDir then begin
 141     TerrasyncDirPage.Values[0] := GetPreviousData( 'TerrasyncDir', ExpandConstant('{reg:HKLM\Software\flightgear.org,TerrasyncDir|{app}\terrasync}') );
 142   end;
 143   Result := True;
 144 end;
 145
 146 function TerrasyncDir(Param: String): String;
 147 begin
 148   Result := TerrasyncDirPage.Values[0];
 149 end;
 150
 151 procedure RegisterPreviousData(PreviousDataKey: Integer);
 152 begin
 153   { Store the settings so we can restore them next time }
 154   SetPreviousData(PreviousDataKey, 'TerrasyncDir', TerrasyncDirPage.Values[0]);
 155 end;
 156
 157 function UpdateReadyMemo(Space, NewLine, MemoUserInfoInfo, MemoDirInfo, MemoTypeInfo, MemoComponentsInfo, MemoGroupInfo, MemoTasksInfo: String): String;
 158 var
 159   S: String;
 160 begin
 161   S := '';
 162   S := S + MemoDirInfo + NewLine + NewLine;
 163   S := S + 'Terrasync folder:' + NewLine;
 164   S := S + Space + TerrasyncDirPage.Values[0] + NewLine + NewLine;
 165   S := S + MemoGroupInfo + NewLine + NewLine;
 166   S := S + MemoTasksInfo + NewLine + NewLine;
 167
 168   Result := S;
 169 end;
 170