New Inno-setup package

diff --git a/package/Win32-Inno/FlightGear.iss b/package/Win32-Inno/FlightGear.iss
new file mode 100644 (file)
index 0000000..cca9a46
--- /dev/null
+++ b/package/Win32-Inno/FlightGear.iss
@@ -0,0 +1,91 @@
+; Script generated by the Inno Setup Script Wizard.
+; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!
+;
+; This script creates an installable FlightGear package for Win32 using the
+; "Inno Setup" package builder.  Inno Setup is free (but probably not open
+; source?.)  The official web site for this package building software is:
+;
+;     http://www.jrsoftware.org/isinfo.php
+;
+; Note: the files must appear in the X: drive.
+; You can do this with the command below:
+;
+;     subst X: path_to_files
+;
+; For example:
+;
+;     C:\> subst X: F:\Path\to\FlightGear\root
+;     C:\> subst X: F:\
+;
+
+[Setup]
+AppName=FlightGear
+OutputBaseFilename=fgsetup-2.0.0-RC2
+AppVerName=FlightGear v2.0.0-RC2
+AppPublisher=The FlightGear Organization
+AppPublisherURL=http://www.flightgear.org
+AppSupportURL=http://www.flightgear.org
+AppUpdatesURL=http://www.flightgear.org
+DefaultDirName={pf}\FlightGear
+DefaultGroupName=FlightGear v2.0.0-RC2
+LicenseFile=X:\data\COPYING
+Uninstallable=yes
+SetupIconFile=x:\flightgear.ico
+VersionInfoVersion=1.9.9.992
+WizardImageFile=X:\setupimg.bmp
+WizardSmallImageFile=X:\setupsmall.bmp
+
+[Tasks]
+; NOTE: The following entry contains English phrases ("Create a desktop icon" and "Additional icons"). You are free to translate them into another language if required.
+Name: "desktopicon"; Description: "Create a &desktop icon"; GroupDescription: "Additional icons:"
+Name: "insoal"; Description: "Install OpenAL (the sound engine)"
+
+[Files]
+; NOTE: run subst X: F:\ (or whatever path the expanded tree resides at)
+Source: "X:\*.txt"; DestDir: "{app}"; Flags: ignoreversion
+Source: "X:\bin\*.*"; DestDir: "{app}\bin"; Flags: ignoreversion recursesubdirs
+Source: "X:\data\*.*"; DestDir: "{app}\data"; Flags: ignoreversion recursesubdirs
+; NOTE: Don't use "Flags: ignoreversion" on any shared system files
+
+[Dirs]
+; Make the user installable scenery directory
+Name: "{app}\scenery"; Permissions: everyone-modify
+Name: "{app}\terrasync"; Permissions: everyone-modify
+
+[Icons]
+Name: "{group}\FlightGear Launcher"; Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}";
+; Name: "{group}\FlightGear"; Filename: "{app}\bin\Win32\fgfs.exe"; Parameters: "--fg-root=."; WorkingDir: "{app}";
+Name: "{group}\FlightGear Manual"; Filename: "{app}\data\Docs\getstart.pdf"
+Name: "{group}\FlightGear Documentation"; Filename: "{app}\data\Docs\index.html"
+Name: "{group}\Flightgear Wiki"; Filename: "http://wiki.flightgear.org"
+Name: "{userdesktop}\FlightGear v2.0.0-RC2"; Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}"; Tasks: desktopicon
+
+Name: "{group}\Tools\Install & Uninstall Scenery"; Filename: "{app}\bin\Win32\fgadmin.exe"; WorkingDir: "{app}";
+Name: "{group}\Tools\TerraSync"; Filename: "{app}\bin\Win32\terrasync.exe"; Parameters: "-S -p 5505 -d ""{app}\terrasync"""; WorkingDir: "{app}";
+Name: "{group}\Tools\Uninstall FlightGear"; Filename: "{uninstallexe}"
+
+Name: "{group}\Tools\fgjs"; Filename: "cmd"; Parameters: "/k fgjs.exe ""--fg-root={app}\data"""; WorkingDir: "{app}\bin\Win32";
+Name: "{group}\Tools\GPSsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\GPSsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
+Name: "{group}\Tools\UGsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\UGsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
+Name: "{group}\Tools\MIDSsmooth"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\MIDSsmooth.exe"" -h"; WorkingDir: "{app}\bin\Win32";
+Name: "{group}\Tools\metar"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\metar.exe"" -h"; WorkingDir: "{app}\bin\Win32";
+Name: "{group}\Tools\yasim"; Filename: "cmd"; Parameters: "/k ""{app}\bin\Win32\yasim.exe"" -h"; WorkingDir: "{app}\bin\Win32";
+
+Name: "{group}\Tools\Explore Documentation Folder"; Filename: "{app}\data\Docs"
+
+; For running flightgear directly
+; Name: "{userdesktop}\FlightGear v2.0.0"; Filename: "{app}\bin\Win32\fgfs.exe"; Parameters: "--fg-root=."; WorkingDir: "{app}"; Tasks: desktopicon
+
+[Run]
+Filename: "{app}\bin\vcredist_x86.exe"; WorkingDir: "{app}"; Parameters: "/qb!"; Description: "Installing Flightgear prerequisites"
+
+; Put installation directory into the fgrun.prefs
+filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}\bin\Win32"; Parameters: "--silent ""--fg-exe={app}\bin\Win32\fgfs.exe"" ""--fg-root={app}\data"" ""--fg-scenery={app}\data\Scenery;{app}\scenery;{app}\terrasync"""
+
+; Put installation and source directories into the fgadmin.prefs
+filename: "{app}\bin\Win32\fgadmin.exe"; WorkingDir: "{app}\bin\Win32"; Parameters: "--silent ""--install-source={src}\..\Scenery"" ""--scenery-dest={app}\scenery"""
+
+Filename: "{app}\bin\OpenAL\oalinst.exe"; WorkingDir: "{app}"; Description: "Installing OpenAL"; Tasks: insoal
+
+Filename: "{app}\bin\Win32\fgrun.exe"; WorkingDir: "{app}"; Description: "Launch FlightGear"; Flags: postinstall skipifsilent
+